Jump to content


Photo

Kill switch code placement


  • Please log in to reply
3 replies to this topic

#1 colintheraven

colintheraven

    Newbie

  • Members
  • Pip
  • 5 posts
  • LocationOhio, USA

Posted 29 March 2014 - 09:27 PM

My son and I are having some trouble with the kill switch code placement. Could you tell me where to put it within the code that's already there? I'm not sure where an "if" should go in relation to the rest of the program.


  • 0

#2 Nathan House

Nathan House

    Administrator

  • Administrators
  • 122 posts
  • LocationLynchburg, VA

Posted 29 March 2014 - 10:59 PM

Hi, I moved your question to a new topic since it's separate from that other topic.

 

The kill switch code should go inside of the loop() function, like this:

void loop()
{
    if(digitalRead(2) == HIGH) // if the push button switch was pressed
    {
        while(1)
        {
            leftMotor.write(90);
            rightMotor.write(90);
        }
    }

    // ... other code here
}

If you look at the bottom of the programming section of the tutorial, you can find this full example program:

#include <Servo.h>

// create servo objects
Servo leftMotor;
Servo rightMotor;

const int serialPeriod = 250;       // only print to the serial console every 1/4 second
unsigned long timeSerialDelay = 0;

const int loopPeriod = 20;          // a period of 20ms = a frequency of 50Hz
unsigned long timeLoopDelay   = 0;

// specify the trig & echo pins used for the ultrasonic sensors
const int ultrasonic2TrigPin = 8;
const int ultrasonic2EchoPin = 9;

int ultrasonic2Distance;
int ultrasonic2Duration;

// define the states
#define DRIVE_FORWARD     0
#define TURN_LEFT         1

int state = DRIVE_FORWARD; // 0 = drive forward (DEFAULT), 1 = turn left

void setup()
{
    Serial.begin(9600);
  
    // ultrasonic sensor pin configurations
    pinMode(ultrasonic2TrigPin, OUTPUT);
    pinMode(ultrasonic2EchoPin, INPUT);
    
    leftMotor.attach(13);
    rightMotor.attach(12);
}


void loop()
{
    if(digitalRead(2) == HIGH) // if the push button switch was pressed
    {
        while(1)
        {
            leftMotor.write(90);
            rightMotor.write(90);
        }
    }

    debugOutput(); // prints debugging messages to the serial console
    
    if(millis() - timeLoopDelay >= loopPeriod)
    {
        readUltrasonicSensors(); // read and store the measured distances
        
        stateMachine();
        
        timeLoopDelay = millis();
    }
}


void stateMachine()
{
    if(state == DRIVE_FORWARD) // no obstacles detected
    {
        if(ultrasonic2Distance > 6 || ultrasonic2Distance < 0) // if there's nothing in front of us (note: ultrasonicDistance will be negative for some ultrasonics if there's nothing in range)
        {
            // drive forward
            rightMotor.write(180);
            leftMotor.write(0);
        }
        else // there's an object in front of us
        {
            state = TURN_LEFT;
        }
    }
    else if(state == TURN_LEFT) // obstacle detected -- turn left
    {
        unsigned long timeToTurnLeft = 500; // it takes around .5 seconds to turn 90 degrees
        
        unsigned long turnStartTime = millis(); // save the time that we started turning

        while((millis()-turnStartTime) < timeToTurnLeft) // stay in this loop until timeToTurnLeft (.5 seconds) has elapsed
        {
            // turn left
            rightMotor.write(180);
            leftMotor.write(180);
        }
        
        state = DRIVE_FORWARD;
    }
}


void readUltrasonicSensors()
{
    // ultrasonic 2
    digitalWrite(ultrasonic2TrigPin, HIGH);
    delayMicroseconds(10);                  // must keep the trig pin high for at least 10us
    digitalWrite(ultrasonic2TrigPin, LOW);
    
    ultrasonic2Duration = pulseIn(ultrasonic2EchoPin, HIGH);
    ultrasonic2Distance = (ultrasonic2Duration/2)/29;
}


void debugOutput()
{
    if((millis() - timeSerialDelay) > serialPeriod)
    {
        Serial.print("ultrasonic2Distance: ");
        Serial.print(ultrasonic2Distance);
        Serial.print("cm");
        Serial.println();
        
        timeSerialDelay = millis();
    }
}

Let me know if you have any questions, I'm more than happy to help!


  • 0

#3 colintheraven

colintheraven

    Newbie

  • Members
  • Pip
  • 5 posts
  • LocationOhio, USA

Posted 30 March 2014 - 11:47 PM

Great! Thanks Nathan. I really appreciate it. I will let you know how it goes.


  • 0

#4 colintheraven

colintheraven

    Newbie

  • Members
  • Pip
  • 5 posts
  • LocationOhio, USA

Posted 31 March 2014 - 03:46 PM

That worked very well. Thanks.


  • 1




1 user(s) are reading this topic

0 members, 1 guests, 0 anonymous users